silviosbs
(usa Suse)
Enviado em 26/07/2012 - 07:32h
Opa, segue o conteúdo de um dos arquivos, no entanto são dezenas deles que tenho para executar,
o estranho que à alguns dias atrás funcionava certinho, não foi feito nenhuma alteração no servidor, e fiz o teste em mais de uma estação e nada.
desde já agradeço.
@echo off
setlocal
REM *********************************************************************
REM EDIT THE NEXT STATEMENT TO SET THE PATH TO THE IPEM INSTALL DIRECTORY
REM DO NOT USE ANY SPACES IN THE PATH
if "%IPEM_DIR%" == "" set IPEM_DIR=C:\ProgrSCM\siemens\ipem
REM *********************************************************************
REM *********************************************************************
REM * ITI PROVIDES THIS PROGRAM AS IS AND WITH ALL FAULTS. ITI *
REM * SPECIFICALLY DISCLAIMS ANY IMPLIED WARRANTY OF MERCHANTABILITY OR *
REM * FITNESS FOR A PARTICULAR USE. ITI DOES NOT WARRANT THAT *
REM * THE OPERATION OF THE PROGRAM WILL BE UNINTERRUPTED OR ERROR FREE. *
REM * *
REM * Copyright (C) 2007 International TechneGroup Incorporated *
REM * 5303 DuPont Circle *
REM * Milford, Ohio 45150, U.S.A. All Rights Reserved. *
REM *********************************************************************
REM This script is used to start Pro/ENGINEER from the Portal.
REM
REM Usage:
REM ProE path
REM
REM where "path" is the path to an instruction file (refer to the
REM ipemexport document for information on the instruction file format).
REM Sanity tests.
if not exist "%IPEM_DIR%" goto no_ipem
if not exist "%IPEM_DIR%\startpro_sync.bat" goto bad_ipem
if "%*" == "" goto no_filepath
REM Eliminate spaces from the path to the instruction file, just to
REM be safe. The trick we use does not work on Windows NT, so we
REM still have to be careful about spaces if the conversion fails.
call :shortnames INSTR_FILE "%*"
if "%INSTR_FILE%" == "" set INSTR_FILE=%*
REM Assume Pro/ENGINEER should be started in the same directory where
REM the Portal put the instruction file. The trick we use to extract
REM the directory from the file path does not work on Windows NT,
REM so if the extraction fails, we do not change the directory.
call :getdir START_DIR "%INSTR_FILE%"
if not "%START_DIR%" == "" cd /D "%START_DIR%"
REM Start Pro/ENGINEER.
if "%STARTPRO_CMD%" == "" set STARTPRO_CMD=%IPEM_DIR%\startpro_sync
call "%STARTPRO_CMD%" "+ipem_open:%INSTR_FILE%" >nul 2>&1
goto end
:no_ipem
echo The Teamcenter Integration for Pro/ENGINEER (iPEM) directory cannot be found.
echo Please check the IPEM_DIR definition in your environment
echo or in %0
goto end
:bad_ipem
echo The path to the Teamcenter Integration for Pro/ENGINEER (iPEM) directory is wrong.
echo Please check the IPEM_DIR definition in your environment
echo or in %0
goto end
:no_filepath
echo No instruction file specified.
echo Usage: ProE instruction_file_path
goto end
REM Extract the directory path from a file path.
REM
REM Usage:
REM CALL :GETDIR var path
REM
REM where "var" is the name of an environment variable to which
REM the resulting directory path will be assigned, and "path" is
REM the path to a file from which the directory will be extracted.
REM If the path has spaces in it, the second argument must be
REM enclosed in quotes.
REM
REM This does not work on Windows NT; "var" will be empty.
:getdir
set %1=%~dp2
goto :eof
REM Convert a path to DOS short names.
REM
REM Usage:
REM CALL :SHORTNAMES var path
REM
REM where "var" is the name of an environment variable to which
REM the converted path will be assigned, and "path" is the path
REM to convert to short names. If the path has spaces in it,
REM the second argument must be enclosed in quotes.
REM
REM This does not work on Windows NT; "var" will be empty.
:shortnames
set %1=%~s2
goto :eof
:end
endlocal
